mirror of
https://github.com/ldc-developers/ldc.git
synced 2025-05-01 15:40:55 +03:00
f457ab78a2
Since this function is only ever invoked from the base directory of the
LDC source tree, it does not need to recurse in order to get the correct
git revision for LDC. This patch therefore adds a parameter that can be
set to `TRUE` or `FALSE` depending on whether one wants to use recursion
or not, and sets it to false in when calling `get_git_head_revision` in
LDC's own `CMakeLists.txt`.
This should prevent issues that arise when building from source tarballs
that have been extracted into a subdirectory of another git tree (!).
This is unfortunately a real possibility: apart from folks using git to
version their home directory [1], it has also proven an issue when using
source tarballs to build the LDC snap package [2].
[1]42946460
[2]https://github.com/ldc-developers/ldc2.snap/issues/21#issuecomment-287575769
Fixes https://github.com/ldc-developers/ldc/issues/2042.
115 lines
3.8 KiB
CMake
115 lines
3.8 KiB
CMake
# - Returns a version string from Git
|
|
#
|
|
# These functions force a re-configure on each git commit so that you can
|
|
# trust the values of the variables in your build system.
|
|
#
|
|
# get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
|
|
#
|
|
# Returns the refspec and sha hash of the current head revision
|
|
#
|
|
# git_describe(<var> [<additional arguments to git describe> ...])
|
|
#
|
|
# Returns the results of git describe on the source tree, and adjusting
|
|
# the output so that it tests false if an error occurs.
|
|
#
|
|
# git_get_exact_tag(<var> [<additional arguments to git describe> ...])
|
|
#
|
|
# Returns the results of git describe --exact-match on the source tree,
|
|
# and adjusting the output so that it tests false if there was no exact
|
|
# matching tag.
|
|
#
|
|
# Requires CMake 2.6 or newer (uses the 'function' command)
|
|
#
|
|
# Original Author:
|
|
# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
|
|
# http://academic.cleardefinition.com
|
|
# Iowa State University HCI Graduate Program/VRAC
|
|
#
|
|
# Copyright Iowa State University 2009-2010.
|
|
# Distributed under the Boost Software License, Version 1.0.
|
|
# (See accompanying file LICENSE_1_0.txt or copy at
|
|
# http://www.boost.org/LICENSE_1_0.txt)
|
|
|
|
if(__get_git_revision_description)
|
|
return()
|
|
endif()
|
|
set(__get_git_revision_description YES)
|
|
|
|
# We must run the following at "include" time, not at function call time,
|
|
# to find the path to this module rather than the path to a calling list file
|
|
get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
|
|
|
|
function(get_git_head_revision _refspecvar _hashvar _use_recursion)
|
|
set(GIT_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
|
|
set(GIT_DIR "${GIT_PARENT_DIR}/.git")
|
|
# if we're not recursing and GIT_DIR does not exist,
|
|
# we are not in git
|
|
if(NOT _use_recursion AND NOT EXISTS "${GIT_DIR}")
|
|
set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
|
|
set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
|
|
return()
|
|
endif()
|
|
# otherwise, either GIT_DIR exists, or we recurse
|
|
# until we find it or we reach the root dir
|
|
while(NOT EXISTS "${GIT_DIR}") # .git dir not found, search parent directories
|
|
set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
|
|
get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
|
|
if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
|
|
# We have reached the root directory, we are not in git
|
|
set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
|
|
set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
|
|
return()
|
|
endif()
|
|
set(GIT_DIR "${GIT_PARENT_DIR}/.git")
|
|
endwhile()
|
|
# check if this is a submodule
|
|
if(NOT IS_DIRECTORY ${GIT_DIR})
|
|
file(READ ${GIT_DIR} submodule)
|
|
string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
|
|
get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
|
|
get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
|
|
endif()
|
|
set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
|
|
if(NOT EXISTS "${GIT_DATA}")
|
|
file(MAKE_DIRECTORY "${GIT_DATA}")
|
|
endif()
|
|
|
|
if(NOT EXISTS "${GIT_DIR}/HEAD")
|
|
return()
|
|
endif()
|
|
set(HEAD_FILE "${GIT_DATA}/HEAD")
|
|
configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
|
|
|
|
configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
|
|
"${GIT_DATA}/grabRef.cmake"
|
|
@ONLY)
|
|
include("${GIT_DATA}/grabRef.cmake")
|
|
|
|
set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
|
|
set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(git_describe _var)
|
|
execute_process(COMMAND
|
|
git
|
|
describe
|
|
${ARGN}
|
|
WORKING_DIRECTORY
|
|
"${CMAKE_SOURCE_DIR}"
|
|
RESULT_VARIABLE
|
|
res
|
|
OUTPUT_VARIABLE
|
|
out
|
|
ERROR_QUIET
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
|
if(NOT res EQUAL 0)
|
|
set(out "${out}-${res}-NOTFOUND")
|
|
endif()
|
|
|
|
set(${_var} "${out}" PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(git_get_exact_tag _var)
|
|
git_describe(out HEAD --exact-match --tag ${ARGN})
|
|
set(${_var} "${out}" PARENT_SCOPE)
|
|
endfunction()
|